sign_message.clsp

;; Copyright 2026 Julia.Social, Inc.
;;
;; Licensed under the Apache License, Version 2.0 (the "License");
;; you may not use this file except in compliance with the License.
;; You may obtain a copy of the License at
;;
;;     http://www.apache.org/licenses/LICENSE-2.0
;;
;; Unless required by applicable law or agreed to in writing, software
;; distributed under the License is distributed on an "AS IS" BASIS,
;; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
;; See the License for the specific language governing permissions and
;; limitations under the License.

(mod (curried-args solution)

  (include *standard-cl-26*)
  (defun print (l x) (i (all "$print$" l x) x x))

  ; Routing root for all paths that reach credential claims.  Supports DID-signed messages, 
  ; timestamps, and nonces as puzzle announcements.

  (include "condition_codes.clib")
  (include "sha256tree.clib")


  (embed-file coin-control-puzzlehash bin "coin_control.clsp.hash.bin")
  (embed-file did-doc-announce-puzzlehash bin "DIDdoc_announce.clsp.hash.bin")
  (embed-file invalidate-puzzlehash bin "invalidate.clsp.hash.bin")
  (embed-file pass-thru-puzzlehash bin "pass_thru.clsp.hash.bin")
  (embed-file present-claims-puzzlehash bin "present_claims.clsp.hash.bin")
  (embed-file present-delegated-puzzlehash bin "present_delegated.clsp.hash.bin")

  ; creates JDIDM puzzle announcements for DID-signed messages
  (defun prepend-messages (messages conditions)
    (if (l messages)
      (c  (list CREATE_PUZZLE_ANNOUNCEMENT (concat "JDIDM" (f messages)))
          (prepend-messages (r messages) conditions))
      conditions
    )
  )

  ; creates a JDIDT puzzle announcement with the signing timestamp
  (defun-inline prepend-datetime (datetime conditions)
    (if datetime
      (c  (list CREATE_PUZZLE_ANNOUNCEMENT (concat "JDIDT" datetime))
          conditions)
      conditions
    )
  )

  ; creates a JDIDN puzzle announcement as an anti-replay nonce
  (defun-inline prepend-nonce (nonce conditions)
    (if nonce
      (c  (list CREATE_PUZZLE_ANNOUNCEMENT (concat "JDIDN" nonce))
          conditions)
      conditions
    )
  )

  ;; main
  (assign
      ( messages
        datetime
        nonce
      ) solution
      child-puzzle-input (r (r (r solution)))
      child-puzzle-output (if (l child-puzzle-input)
                              (assign
                                  child-hash (sha256tree (f child-puzzle-input))
                                (if (if (= child-hash coin-control-puzzlehash) 1
                                    (if (= child-hash did-doc-announce-puzzlehash) 1
                                    (if (= child-hash invalidate-puzzlehash) 1
                                    (if (= child-hash pass-thru-puzzlehash) 1
                                    (if (= child-hash present-claims-puzzlehash) 1
                                        (= child-hash present-delegated-puzzlehash))))))
                                  (a (f child-puzzle-input) (list curried-args (r child-puzzle-input)))
                                  (x 110)
                                )
                              )
                              (list curried-args ())
                          )
      ( child-puzzle-new-curry-args
        child-puzzle-conditions
      ) child-puzzle-output
    (list child-puzzle-new-curry-args
          (prepend-messages messages
            (prepend-datetime datetime
              (prepend-nonce nonce
                child-puzzle-conditions
              )
            )
          )
    )
  )
)