Repository navigation
Expand file tree
/
Copy pathsh2_drawlow.s
More file actions
473 lines (414 loc) · 15 KB
/
Copy pathsh2_drawlow.s
File metadata and controls
473 lines (414 loc) · 15 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
! Original code by Chilly Willy
.section .sdata
.equ DOOMTLS_COLORMAP, 16
.equ DOOMTLS_FUZZPOS, 20
.equ DOOMTLS_FRAMEBUFFER, 24
! Draw a vertical column of pixels from a projected wall texture.
! Source is the top of the column to scale.
!
!void I_DrawColumn(int dc_x, int dc_yl, int dc_yh, int light, fixed_t frac,
! fixed_t fracstep, inpixel_t *dc_source, int dc_texheight)
.align 2
.global _I_DrawColumnLowA
_I_DrawColumnLowA:
add #1,r6
0:
cmp/ge r6,r5
bf/s 1f
sub r5,r6 /* count = dc_yh - dc_yl */
/* dc_yl >= dc_yh, exit */
rts
nop
1:
mov.l r8,@-r15
mov.l r9,@-r15
add r7,r7
mov.l @(DOOMTLS_COLORMAP, gbr),r0
add r0,r7 /* dc_colormap = colormap + light */
mov.l @(DOOMTLS_FRAMEBUFFER, gbr),r0
shll8 r5
mov.l @(8,r15),r2 /* frac */
mov r0,r8 /* frame buffer start */
mov.l @(12,r15),r3 /* fracstep */
add r4,r8 /* fb += dc_x */
add r4,r8 /* fb += dc_x */
add r5,r8
mov.l @(20,r15),r4
shlr2 r5
add r5,r8 /* fb += (dc_yl*256 + dc_yl*64) */
mov.l @(16,r15),r5 /* dc_source */
add #-1,r4 /* heightmask = texheight - 1 */
mov.l draw_width,r1
sub r1,r8 /* fb -= SCREENWIDTH */
swap.w r2,r0 /* (frac >> 16) */
and r4,r0 /* (frac >> 16) & heightmask */
/* test if count & 1 */
shlr r6
movt r9 /* 1 if count was odd */
bt/s do_col_loop_1px
add r9,r6
.p2alignw 1, 0x0009
do_col_loop:
mov.b @(r0,r5),r0 /* pix = dc_source[(frac >> 16) & heightmask] */
add r3,r2 /* frac += fracstep */
add r1,r8 /* fb += SCREENWIDTH */
add r0,r0
mov.w @(r0,r7),r9 /* dpix = dc_colormap[pix] */
swap.w r2,r0 /* (frac >> 16) */
mov.w r9,@r8 /* *fb = dpix */
and r4,r0 /* (frac >> 16) & heightmask */
do_col_loop_1px:
mov.b @(r0,r5),r0 /* pix = dc_source[(frac >> 16) & heightmask] */
add r3,r2 /* frac += fracstep */
add r1,r8 /* fb += SCREENWIDTH */
add r0,r0
mov.w @(r0,r7),r9 /* dpix = dc_colormap[pix] */
swap.w r2,r0 /* (frac >> 16) */
mov.w r9,@r8 /* *fb = dpix */
dt r6 /* count-- */
bf/s do_col_loop
and r4,r0 /* (frac >> 16) & heightmask */
mov.l @r15+,r9
rts
mov.l @r15+,r8
! Draw a vertical column of pixels from a projected wall texture.
! Non-power of 2 texture height.
!
!void I_DrawColumnNPO2(int dc_x, int dc_yl, int dc_yh, int light, fixed_t frac,
! fixed_t fracstep, inpixel_t *dc_source, int dc_texheight)
.align 2
.global _I_DrawColumnNPo2LowA
_I_DrawColumnNPo2LowA:
add #1,r6
0:
cmp/ge r6,r5
bf/s 1f
sub r5,r6 /* count = dc_yh - dc_yl */
/* dc_yl >= dc_yh, exit */
rts
nop
1:
mov.l r8,@-r15
mov.l r9,@-r15
add r7,r7
mov.l @(DOOMTLS_COLORMAP, gbr),r0
add r0,r7 /* dc_colormap = colormap + light */
mov.l @(DOOMTLS_FRAMEBUFFER, gbr),r0
shll8 r5
mov.l @(8,r15),r2 /* frac */
mov r0,r8 /* frame buffer start */
mov.l @(12,r15),r3 /* fracstep */
add r4,r8 /* fb += dc_x */
add r4,r8 /* fb += dc_x */
mov.l @(20,r15),r4
add r5,r8
shlr2 r5
add r5,r8 /* fb += (dc_yl*256 + dc_yl*64) */
mov.l @(16,r15),r5 /* dc_source */
shll16 r4 /* heightmask = texheight << FRACBITS */
mov #0,r0
cmp/ge r0,r2
bt 3f
/* if (frac < 0) */
2:
add r4,r2 /* frac += heightmask */
cmp/ge r0,r2
bf 2b
bt 5f
3:
cmp/ge r4,r2
bf 5f
/* if (frac >= heightmask) */
4:
sub r4,r2 /* frac -= heightmask */
cmp/ge r4,r2
bt 4b
5:
mov.l draw_width,r1
mov r2,r0
shlr16 r0 /* frac >> 16 */
.p2alignw 1, 0x0009
do_cnp_loop:
mov.b @(r0,r5),r0 /* pix = dc_source[frac >> 16] */
cmp/ge r4,r2
add r3,r2 /* frac += fracstep */
add r0,r0
mov.w @(r0,r7),r9 /* dpix = dc_colormap[pix] */
mov r2,r0
bf/s 1f
/* if (frac >= heightmask) */
dt r6 /* count-- */
sub r4,r2 /* frac -= heightmask */
.p2alignw 1, 0x0009
1:
mov.w r9,@r8 /* *fb = dpix */
shlr16 r0 /* frac >> 16 */
bf/s do_cnp_loop
add r1,r8 /* fb += SCREENWIDTH */
mov.l @r15+,r9
rts
mov.l @r15+,r8
! Draw a vertical column of distorted background pixels.
! Source is the top of the column to scale.
! Low detail (doubl-wide pixels) mode.
!
!void I_DrawFuzzColumn(int dc_x, int dc_yl, int dc_yh, int light, fixed_t frac,
! fixed_t fracstep, inpixel_t *dc_source, int dc_texheight)
.align 2
.global _I_DrawFuzzColumnLowA
_I_DrawFuzzColumnLowA:
mov #0,r0
cmp/eq r0,r5
bf 0f
mov #1,r5
0:
mov.l draw_height,r0
mov.w @r0,r0
add #-2,r0
cmp/gt r0,r6
bf 1f
mov r0,r6
1:
add #1,r6
2:
cmp/ge r6,r5
bf/s 3f
sub r5,r6 /* count = dc_yh - dc_yl */
/* dc_yl >= dc_yh, exit */
rts
nop
3:
mov.l @(DOOMTLS_COLORMAP, gbr),r0
mov.l r8,@-r15
mov.l r9,@-r15
add r7,r7
add r0,r7 /* dc_colormap = colormap + light */
mov.l @(DOOMTLS_FRAMEBUFFER, gbr),r0
shll8 r5
mov r0,r8 /* frame buffer start */
add r4,r8 /* fb += dc_x */
add r4,r8 /* fb += dc_x */
add r5,r8
shlr2 r5
add r5,r8 /* fb += (dc_yl*256 + dc_yl*64) */
mov.l draw_fuzzoffset,r5
mov.l draw_width,r1
mov.l @(DOOMTLS_FUZZPOS, gbr),r0 /* pfuzzpos */
add r0,r0
mov r0,r3
and #126,r0 /* fuzzpos &= FUZZMASK */
sub r1,r8 /* fb -= SCREENWIDTH */
.p2alignw 1, 0x0009
do_fuzz_col_loop:
mov.w @(r0,r5),r0 /* pix = fuzztable[fuzzpos] */
add #2,r3
mov.b @(r0,r8),r0 /* pix = dest[pix] */
dt r6 /* count-- */
add r1,r8 /* fb += SCREENWIDTH */
add r0,r0
mov.w @(r0,r7),r4 /* dpix = dc_colormap[pix] */
mov r3,r0
mov.w r4,@r8 /* *fb = dpix */
bf/s do_fuzz_col_loop
and #126,r0 /* fuzzpos &= FUZZMASK */
shlr r3
mov r3,r0
mov.l r0,@(DOOMTLS_FUZZPOS, gbr)
mov.l @r15+,r9
rts
mov.l @r15+,r8
! Draw a horizontal row of pixels from a projected flat (floor/ceiling) texture.
!
!void I_DrawSpan(int ds_y, int ds_x1, int ds_x2, int light, fixed_t ds_xfrac,
! fixed_t ds_yfrac, fixed_t ds_xstep, fixed_t ds_ystep,
! inpixel_t *ds_source, int ds_height)
.align 2
.global _I_DrawSpanLowA
_I_DrawSpanLowA:
add #1,r6
0:
cmp/ge r6,r5
bf/s 1f
sub r5,r6 /* count = ds_x2 - ds_x1 */
/* dc_yl >= dc_yh, exit */
rts
nop
1:
mov.l r8,@-r15
mov.l r9,@-r15
mov.l r10,@-r15
mov.l r11,@-r15
mov.l r12,@-r15
add r7,r7
mov.l @(DOOMTLS_COLORMAP, gbr),r0
add r0,r7 /* ds_colormap = colormap + light */
mov.l @(DOOMTLS_FRAMEBUFFER, gbr),r0
shll8 r4
mov r0,r8 /* frame buffer start */
add r6,r5
add r5,r5
add r5,r8
add r4,r8
shlr2 r4
add r4,r8 /* fb += (ds_y*256 + ds_y*64) */
mov.l @(36,r15),r9 /* ds_source */
mov.l @(40,r15),r11 /* ds_height */
mov r11,r12
dt r12 /* (ds_height-1) */
mulu.w r12,r11 /* (ds_height-1) * ds_height */
mov.l @(20,r15),r2 /* xfrac */
mov.l @(28,r15),r3 /* xstep */
sts macl,r11 /* draw_flat_ymask */
dmuls.l r3,r6
mov.l @(24,r15),r4 /* yfrac */
mov.l @(32,r15),r5 /* ystep */
sts macl,r10
add r10,r2 /* xfrac += xstep * count */
dmuls.l r5,r6
swap.w r2,r0 /* (xfrac >> 16) */
and r12,r0 /* (xfrac >> 16) & 63 */
sts macl,r10
add r10,r4 /* yfrac += ystep * count */
swap.w r4,r1 /* (yfrac >> 16) */
and r11,r1 /* (yfrac >> 16) & 63*64 */
or r1,r0 /* spot = ((yfrac >> 16) & *64) | ((xfrac >> 16) & 63) */
/* test if count & 1 */
shlr r6
movt r1 /* 1 if count was odd */
bt/s do_span_loop_1px
add r1,r6
.p2alignw 1, 0x0009
do_span_loop:
mov.b @(r0,r9),r0 /* pix = ds_source[spot] */
sub r3,r2 /* xfrac -= xstep */
sub r5,r4 /* yfrac -= ystep */
add r0,r0
mov.w @(r0,r7),r10 /* dpix = ds_colormap[pix] */
swap.w r4,r1 /* (yfrac >> 16) */
swap.w r2,r0 /* (xfrac >> 16) */
and r12,r0 /* (xfrac >> 16) & 63 */
mov.w r10,@-r8 /* *--fb = dpix */
and r11,r1 /* (yfrac >> 16) & 63*64 */
or r1,r0 /* spot = ((yfrac >> 16) & *64) | ((xfrac >> 16) & 63) */
do_span_loop_1px:
dt r6 /* count-- */
mov.b @(r0,r9),r0 /* pix = ds_source[spot] */
sub r3,r2 /* xfrac -= xstep */
sub r5,r4 /* yfrac -= ystep */
add r0,r0
mov.w @(r0,r7),r10 /* dpix = ds_colormap[pix] */
swap.w r4,r1 /* (yfrac >> 16) */
swap.w r2,r0 /* (xfrac >> 16) */
and r12,r0 /* (xfrac >> 16) & 63 */
mov.w r10,@-r8 /* *--fb = dpix */
and r11,r1 /* (yfrac >> 16) & 63*64 */
bf/s do_span_loop
or r1,r0 /* spot = ((yfrac >> 16) & *64) | ((xfrac >> 16) & 63) */
mov.l @r15+,r12
mov.l @r15+,r11
mov.l @r15+,r10
mov.l @r15+,r9
rts
mov.l @r15+,r8
! Draw a horizontal row of pixels from a projected flat (floor/ceiling) texture.
!
!void I_DrawSpan(int ds_y, int ds_x1, int ds_x2, int light, fixed_t ds_xfrac,
! fixed_t ds_yfrac, fixed_t ds_xstep, fixed_t ds_ystep,
! inpixel_t *ds_source, int ds_height)
.align 2
.global _I_DrawSpanLowSwapA
_I_DrawSpanLowSwapA:
add #1,r6
0:
cmp/ge r6,r5
bf/s 1f
sub r5,r6 /* count = ds_x2 - ds_x1 */
/* dc_yl >= dc_yh, exit */
rts
nop
1:
mov.l r8,@-r15
mov.l r9,@-r15
mov.l r10,@-r15
mov.l r11,@-r15
mov.l r12,@-r15
add r7,r7
mov.l @(DOOMTLS_COLORMAP, gbr),r0
add r0,r7 /* ds_colormap = colormap + light */
mov.l @(DOOMTLS_FRAMEBUFFER, gbr),r0
shll8 r4
mov r0,r8 /* frame buffer start */
add r6,r5
add r5,r8
add r5,r8
add r4,r8
shlr2 r4
add r4,r8 /* fb += (ds_y*256 + ds_y*64) */
mov.l @(36,r15),r9 /* ds_source */
mov.l @(40,r15),r11 /* ds_height */
mov r11,r12
dt r12 /* (ds_height-1) */
mulu.w r12,r11 /* (ds_height-1) * ds_height */
mov.l @(20,r15),r2 /* xfrac */
mov.l @(28,r15),r3 /* xstep */
sts macl,r11 /* draw_flat_ymask */
dmuls.l r3,r6
mov.l @(24,r15),r4 /* yfrac */
mov.l @(32,r15),r5 /* ystep */
sts macl,r10
add r10,r2 /* xfrac += xstep * count */
dmuls.l r5,r6
swap.w r2,r0 /* (xfrac >> 16) */
and r12,r0 /* (xfrac >> 16) & 63 */
sts macl,r10
add r10,r4 /* yfrac += ystep * count */
swap.w r4,r1 /* (yfrac >> 16) */
and r11,r1 /* (yfrac >> 16) & 63*64 */
or r1,r0 /* spot = ((yfrac >> 16) & *64) | ((xfrac >> 16) & 63) */
/* test if count & 1 */
shlr r6
movt r1 /* 1 if count was odd */
bt/s do_spansw_loop_1px
add r1,r6
.p2alignw 1, 0x0009
do_spansw_loop:
mov.b @(r0,r9),r0 /* pix = ds_source[spot] */
sub r3,r2 /* xfrac -= xstep */
sub r5,r4 /* yfrac -= ystep */
add r0,r0
mov.w @(r0,r7),r10 /* dpix = ds_colormap[pix] */
swap.w r4,r1 /* (yfrac >> 16) */
swap.w r2,r0 /* (xfrac >> 16) */
and r12,r0 /* (xfrac >> 16) & 63 */
and r11,r1 /* (yfrac >> 16) & 63*64 */
swap.b r10,r10
mov.w r10,@-r8 /* *--fb = dpix */
or r1,r0 /* spot = ((yfrac >> 16) & *64) | ((xfrac >> 16) & 63) */
do_spansw_loop_1px:
mov.b @(r0,r9),r0 /* pix = ds_source[spot] */
sub r3,r2 /* xfrac -= xstep */
sub r5,r4 /* yfrac -= ystep */
add r0,r0
mov.w @(r0,r7),r10 /* dpix = ds_colormap[pix] */
swap.w r4,r1 /* (yfrac >> 16) */
swap.w r2,r0 /* (xfrac >> 16) */
and r12,r0 /* (xfrac >> 16) & 63 */
and r11,r1 /* (yfrac >> 16) & 63*64 */
swap.b r10,r10
mov.w r10,@-r8 /* *--fb = dpix */
dt r6 /* count-- */
bf/s do_spansw_loop
or r1,r0 /* spot = ((yfrac >> 16) & *64) | ((xfrac >> 16) & 63) */
mov.l @r15+,r12
mov.l @r15+,r11
mov.l @r15+,r10
mov.l @r15+,r9
rts
mov.l @r15+,r8
.align 2
draw_width:
.long 320
draw_height:
.long _viewportHeight
draw_fuzzoffset:
.long _fuzzoffset